it-swarm-ru.tech

Пакет для определения, является ли система 32-битной или 64-битной

Кто-нибудь знает, как создать командный файл, который может Shell одной программы, если это 64-разрядная система или Shell другой, если это 32-разрядная система?

17
philip

Проверьте, является ли %PROCESSOR_ARCHITECTURE%x86:

if %PROCESSOR_ARCHITECTURE%==x86 (
  rem 32 bit
) else (
  rem 64 bit
)

По крайней мере, пока. На сервере у меня есть доступ к его AMD64, но я не знаю, например, как выглядит Itanium. Но 32-битные версии всегда сообщают x86.

Еще один вариант, который также работает на WoW64:

for /f "skip=1 delims=" %%x in ('wmic cpu get addresswidth') do if not defined AddressWidth set AddressWidth=%%x

if %AddressWidth%==64 (
  rem 64 bit
) else (
  rem 32 bit
)
23
Joey

Он работает и без WMI! Я предлагаю:

 @echo off
 if /i "%processor_architecture%"=="AMD64" GOTO AMD64
 if /i "%PROCESSOR_ARCHITEW6432%"=="AMD64" GOTO AMD64
 if /i "%processor_architecture%"=="x86" GOTO x86
 GOTO ERR
 :AMD64
    rem do AMD64 stuff
 GOTO EXEC
 :x86
    rem do x86 stuff
 GOTO EXEC
 :EXEC
    rem do Arch independent stuff
 GOTO END
 :ERR
 @echo Unsupported architecture "%processor_architecture%"!
 pause
 :END
12
Josef
uname -a #for mac

uname -i #for ubuntu
5
ajmartin

И простым способом было бы проверить наличие папки %SystemRoot%\SysWOW64. Хотя он не на 100% надежен, он действительно хорош для определения, является ли система 64-битной.

3
Mehrdad

Все партии там не работают в моей Windows 8 x64.

Следующая работа со мной:

@cd %programfiles(x86)%\

@if %ERRORLEVEL% == 0 (echo x64&&pause)

@if %ERRORLEVEL% == 1 (echo x86&&pause)
2
ducanhnguyen2k

Эта линия даст вам то, что вы хотите, работает на XP, Vista и 7

сохранить как .bat или .cmd

If Defined ProgramFiles(x86) (\\Fileserver\Distribution\Softwarex64.exe) else (\\Fileserver\Distribution\Softwarex86.exe)

Если источник установки на локальном компьютере просто указывает на него (D:\Programs\Softwarex64.exe)

и если вы хотите просто запускать команды, а не устанавливать, просто введите команду, которую вы хотите для x64 Between first (), и команды для x86 Between second ()

If Defined ProgramFiles(x86) (ipconfig /all & @echo  This Is A 64-bit System ) else (arp -a & @echo This Is A 32-bit System)

Скопируйте это в свой CMD, чтобы проверить это 

Надеюсь, это поможет

1
Match

В Linux вы можете просто использовать «Arch» в командной строке.

ubuntu# Arch
x86_64

В OSX (Snow Leopard) он возвращает «i386», даже если вы используете 64-битное оборудование.

0
Preston Lee
0
michael

Приведенный ниже метод должен быть достаточно надежным, поскольку он будет работать, даже если переменные окружения были испорчены:

rem If no kernel32.dll in System32, probably running on DOS or 16-bit Windows
if not exist "%SystemRoot%\System32\kernel32.dll" goto DOS

rem If no kernel32.dll in SysWOW64, likely a 32-bit Windows 
if not exist "%SystemRoot%\SysWOW64\kernel32.dll" goto WIN32

rem If file size reported for kernel32.dll located in System32 and SysWOW64 is
rem the same, it likely means that System32 is being redirected to SysWOW64.
rem This would be the case for 32-bit version of cmd.exe running on 64-bit OS. 
for %%I in ("%SystemRoot%\SysWOW64\kernel32.dll") do (
  for %%J in ("%SystemRoot%\System32\kernel32.dll") do (
    if "%%~zI" equ "%%~zJ" goto WOW64
  )
)

rem If we get this far, the script is likely running in native 64-bit console
echo Native Shell on 64-bit Windows
rem ...
exit /b

:WOW64
echo 32-bit Shell on 64-bit Windows (WOW64)
rem ...
exit /b

:WIN32
echo 32-bit Windows
rem ...
goto END

:DOS
echo DOS or 16-bit Windows
rem ...
goto END

rem ...

:END
rem We can put this label at the end of the file to allow exiting script on 
rem older systems that do not support 'exit /b'

Этот метод основан на том факте, что «% WINDIR%\System32\kernel32.dll» должен присутствовать во всех системах Windows. 64-разрядные версии Windows также включают каталог «% WINDIR%\SysWOW64», содержащий 32-разрядные версии системных файлов, которых нет в 32-разрядных системах. 

В 64-разрядных системах 32-разрядные приложения перенаправляются на SysWOW64 при попытке доступа к файлам в System32. Таким образом, если мы получаем одинаковый размер kernel32.dll как из System32, так и из SysWOW64, это означает, что перенаправление действует, и наш скрипт выполняется в 32-разрядной консоли на 64-разрядной ОС. 

0
R.G.